name "kxm 530"
copyright "2009. stylus, http://stylus.siteboard.de"
engine "kX"
created "07/08/2009"  
comment "8 band fixed filter bank (6x bp, lp, hp) with resonance control, (kxm 530 v1.0)"
guid "980080e1-f6e0-4261-87c8-f33bb3ad669e"

; registers
input in
output out
static hp1, bp1, lp1
static hp2, bp2, lp2 
static hp3, bp3, lp3
static hp4, bp4, lp4
static hp5, bp5, lp5
static hp6, bp6, lp6
static hp7, bp7, lp7
static hp8, bp8, lp8 
static in1, in2, in3, in4 
static in5, in6, in7, in8
static q1, t
temp c
control _88hz, _125hz, _250hz, _500hz 
control _1000hz, _2000hz, _4000hz, _5600hz
control q=0 

; trim q
interp q1, 1, q, 0.1
 
; band feed
macs in1, 0 ,in, _88hz
macs in2, 0 ,in, _125hz
macs in3, 0 ,in, _250hz
macs in4, 0 ,in, _500hz  
macs in5, 0 ,in, _1000hz
macs in6, 0 ,in, _2000hz
macs in7, 0 ,in, _4000hz
macs in8, 0 ,in, _5600hz

; fixed state variable filters  
; band mix from "moog 907" and "moog 914" (6, 12 bpf's) 
; additional resonance control to make higher slopes 
; lp, hp: -12 db/octave
; bp: - 6db/octave

; lowpass 
macsn t, in1, lp1 , 1 
macsn hp1, t, q1, bp1 ; q
macs  bp1, bp1, 0.0115, hp1
macs  lp1, lp1 , 0.0115, bp1 ; cutoff   

; bandpasses
macsn t, in2, lp2 , 1 
macsn hp2, t, q1, bp2 ; q
macs  bp2, bp2, 0.0164, hp2
macs  lp2, lp2 , 0.0164, bp2 ; cutoff

macsn t, in3, lp3 , 1 
macsn hp3, t, q1, bp3 ; q
macs  bp3, bp3, 0.0327, hp3
macs  lp3, lp3 , 0.0327, bp3 ; cutoff

macsn t, in4, lp4 , 1 
macsn hp4, t, q1, bp4 ; q
macs  bp4, bp4, 0.0654, hp4
macs  lp4, lp4 , 0.0654, bp4 ; cutoff 

macsn t, in5, lp5 , 1 
macsn hp5, t, q1, bp5 ; q
macs  bp5, bp5, 0.1308, hp5
macs  lp5, lp5 , 0.1308, bp5 ; cutoff

macsn t, in6, lp6 , 1 
macsn hp6, t, q1, bp6 ; q
macs  bp6, bp6, 0.2611, hp6
macs  lp6, lp6 , 0.2611, bp6 ; cutoff

macsn t, in7, lp7 , 1 
macsn hp7, t, q1, bp7 ; q
macs  bp7, bp7, 0.5716, hp7
macs  lp7, lp7 , 0.5716, bp7 ; cutoff

; highpass
macsn t, in8, lp8 , 1 
macsn hp8, t, q1, bp8 ; q
macs  bp8, bp8, 0.7167, hp8
macs  lp8, lp8 , 0.7167, bp8 ; cutoff

; output sum
acc3 c, lp1, bp2, bp3
acc3 c, c, bp4, bp5
acc3 c, c, bp6, bp7
acc3 out, c, hp8, 0 

end